ThePortForum.com

Code: Select all

' © 2017 Julian D. A. Wiseman, contactable via www.jdawiseman.com
' Copying and distribution of this file, with or without modification, are permitted in any medium without royalty
' provided the copyright notice and this notice are preserved. This file is offered as-is, without any warranty.

Sub FieldIdentifiers()
	Dim i, j, k, numDifferentIdentifiers, iIndentifierCount(1 To 100) As Integer
	Dim thisIdent, strIdentifier(1 To 100), ans As String
	Dim fld As Field
	Dim thisIdentExists As Boolean

	numDifferentIdentifiers = 0

	For Each fld In ActiveDocument.Fields
		If fld.Type = wdFieldIndexEntry Then
			i = InStr(1, fld.Code.Text, "\f", 1)
			If i = 0 Then
				MsgBox "No \f in “" & fld.Code.Text & "”", 0, "XE missing \f"
			Else
				thisIdent = Mid(fld.Code.Text, i + 3, Len(fld.Code.Text) - i - 3)
				thisIdentExists = False
				For j = 1 To numDifferentIdentifiers
					If thisIdent = strIdentifier(j) Then
						iIndentifierCount(j) = 1 + iIndentifierCount(j)
						thisIdentExists = True
						Exit For
					End If  ' thisIdent = strIdentifier(j)
				Next j
				If Not (thisIdentExists) Then
					numDifferentIdentifiers = 1 + numDifferentIdentifiers
					strIdentifier(numDifferentIdentifiers) = thisIdent
					iIndentifierCount(numDifferentIdentifiers) = 1
				End If  ' Not(thisIdentExists)
			End If	' i=0
		End If  ' wdFieldIndexEntry
	Next fld
	' Sort, not efficiently as done once and list not long
	For i = 1 To numDifferentIdentifiers - 1: For j = i + 1 To numDifferentIdentifiers
		If strIdentifier(j) < strIdentifier(i) Then
			ans = strIdentifier(j): strIdentifier(j) = strIdentifier(i): strIdentifier(i) = ans  ' ans is temp variable
			k = iIndentifierCount(j): iIndentifierCount(j) = iIndentifierCount(i): iIndentifierCount(i) = k  ' k is temp variable
		End If
	Next j: Next i
	ans = "": k = 0
	For j = 1 To numDifferentIdentifiers
		k = k + iIndentifierCount(j)
		' In next line the ‘2’ is approximate, being relative width of digit and space
		ans = ans & Space(2 * (Len(Format(iIndentifierCount(1), "#,##0")) - Len(Format(iIndentifierCount(j), "#,##0")))) _
		& Format(iIndentifierCount(j), "#,##0") & " * " & strIdentifier(j) & vbNewLine
	Next j
	ans = ans & vbNewLine & "Total = " & k
	MsgBox ans, 0, "Frequencies of \f (and subsequent) parameters in XE index entries"
End Sub  ' FieldIdentifiers